64G以上surface3 pro分区代码说明及文件
看到论坛有吧友求助surface分区的帖子，尽管回帖的很多，问题是胡说八道的居多，个别人贴出来的代码直接就是在坑爹，要是按照那样的代码分区，立马悲剧，最后的结果就是进了bios，来回重启，我找了一段一位求助的吧友贴出来的代码，简单的看了下，现在将详细的代码说明贴出来，并附上我已经修改好的C盘50G，分两个分区的分区方案和代码，附上我的i5 4G 128SSD的2个分区的文件，可以直接替换，支持128G及以上硬盘，winboot抽时间在弄，最近和医院有缘了。
话说，这玩意就是批量部署的应答文件而已，用于系统部署时通过调用从而导入到diskpart工具里面，用的着人为的搞的那么复杂么？
convert gpt 将磁盘格式转换为gpt模式
create partition primary size=360 创建一个360MB大小的主分区
set id=DE94BBA4-06D1-4D40-A16A-BFD50179D6AC设置该分区的分区ID
gpt attributes=0x8000000000000001 设置该分区的属性
format quick fs=ntfs label="Windows RE tools" 快速格式化该分区为ntfs格式，并设置分区标签为Windows RE tools
assign letter=T 设置磁盘盘符为M
create partition efi size=200 创建一个200MB大小的efi分区（其实就是efi启动引导分区）
format quick fs=fat32 label="System" 快速格式化所选分区为fat32格式，并设置分区标签为System
assign letter=S 设置磁盘盘符为S
create partition msr size=128 创建一个128MB大小的msr分区（msr为保留分区，具体作用在msdn文档里面查不到，我也不知道）
create partition primary 以剩余的所有磁盘容量创建一个主分区（这里就是重点了，也就是说要改变分区从这里开始）
shrink minimum=4800 将选定的主分区压缩4800MB（这其实是在创建恢复分区，注意选定的还是主分区）
gpt attributes=0x0000000000000000 设置分区属性（这个参数可以在msdn上查到，我对这个没什么研究，都是直接拿来用）
format quick fs=ntfs label="Windows" 快速格式化所选分区为ntfs格式，并设置标签为Windows（没错，这其实就是C盘了，也就是说，默认的其实就是在创建WINRE分区、msr保留分区、efi引导分区以后，将剩余的磁盘空间全部创建一个主分区，再从这个主分区里面压缩出来4800MB用来创建恢复分区，剩下的就是C盘了。）
assign letter=W 设置分区盘符为W
create partition primary 创建一个主分区（由于磁盘剩余部分其实已经用来创建了主分区，而前面对主分区有个压缩4800MB的步骤，压缩出来的4800MB空间是空白的，这里就是在操作这4800MB空间）
set id=de94bba4-06d1-4d40-a16a-bfd50179d6ac 设置分区ID
gpt attributes=0x8000000000000001 设置分区属性
format quick fs=ntfs label="Recovery image" 格式化并设置标签
assign letter=R 设置盘符
rescan 刷新分区
exit 退出
可能比较乱，将就着看吧，我想我说的已经够清楚了，要是还看不懂，那我真的没辙了！下面贴上我修改的代码，大家可以对照着看：
convert gpt
create partition primary size=360
set id=DE94BBA4-06D1-4D40-A16A-BFD50179D6AC
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Windows RE tools"
assign letter=T
create partition efi size=200
format quick fs=fat32 label="System"
assign letter=S
create partition msr size=128
create partition primary size=51208
gpt attributes=0x0000000000000000
format quick fs=ntfs label="Windows"
assign letter=W
create partition primary
shrink minimum=5300
format quick fs=ntfs label="Software"
assign letter=V
create partition primary
set id=de94bba4-06d1-4d40-a16a-bfd50179d6ac
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Recovery image"
assign letter=R
rescan
exit
实际分区效果图：
楼主，磁盘图标显示锁的图标是什么啊？ 与时俱进come 发表于 2015-5-9 23:28 http://cdn.pcbeta.img.inimc.com/static/image/common/back.gif
楼主，磁盘图标显示锁的图标是什么啊？
表示Bitlocker 这个分享的不错，一直没能完全理解里面的内容，现在豁然开朗了 厉害 不错滴答滴答滴答滴答滴答 Richardrobinson 发表于 2015-5-10 08:50 http://cdn.pcbeta.img.inimc.com/static/image/common/back.gif
这个分享的不错，一直没能完全理解里面的内容，现在豁然开朗了
能帮到你就好 与时俱进come 发表于 2015-5-9 23:28 http://cdn.pcbeta.img.inimc.com/static/image/common/back.gif
楼主，磁盘图标显示锁的图标是什么啊？
系统自带的保护和加密软件，bitlocker，挺有用的 谢谢分享，太给力了 小白看了半天没有明白是怎么操作，在什么环境下进行呢？ vern 发表于 2015-6-8 23:38 http://cdn.pcbeta.img.inimc.com/static/image/common/back.gif
小白看了半天没有明白是怎么操作，在什么环境下进行呢？
这直接编辑就可以了啊，桌面环境就行 你好，按照你的方法，完成后出现了这样的情况，是什么原因呢
我的CreatePartitions-UEFI，改好后是这样的
convert gpt
create partition primary size=390
set id=DE94BBA4-06D1-4D40-A16A-BFD50179D6AC
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Windows RE tools"
assign letter=T
create partition efi size=200
format quick fs=fat32 label="System"
assign letter=S
create partition msr size=128
create partition primary size=51208
gpt attributes=0x0000000000000000
format quick fs=ntfs label="Windows"
assign letter=W
create partition primary
shrink minimum=5000
format quick fs=ntfs label="software"
assign letter=V
create partition primary
set id=de94bba4-06d1-4d40-a16a-bfd50179d6ac
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Recovery image"
assign letter=R
rescan
exit
之后重新安装，安装一切正常，完成后，就是一个问题，D盘出现一个文件夹
就是这个文件夹《ReoveryImage》，经过确认，确实是将应该安装到恢复分区的文件，安装到了D盘。
这是怎么回事呢？
學習一下。 谢谢分享，感谢高手 我看看这个 谢谢分享！！！
页:
[1]