关于Vmware虚拟机安装Mac OS X 时unlocker补丁不起效（个人见解）
玩过vmware的亲应该都知道，vmware在新建虚拟机过程中，选择客户机操作系统页面并无Apple系统，因此才需要unlocker补丁（最新应该是unlocker208）。不过很多时候用管理员权限运行“win-install.cmd"后再次打开虚拟机依旧没有Apple系统（客户机操作系统页面）。我个人使用的一种方法：用记事本打开”win-install.cmd"，找到
echo Patching...
C:\Python27\python.exe vmxsmc.py
这里有要注意的，在vmxsmc.py前的是你电脑安装的Python27软件的安装路径（如果文件中所写路径与你的电脑中Python27软件安装路径不一致的话修改即可）没安装的话则需要去找该软件安装，安装时注意只能是放在硬盘根目录下，如C:\Python27\python.exe，D:\Python27\python.exe,E:\Python27\python.exe，以此类推。至于vmxsmc.py一般改成unlocker.py，以上准备工作完毕后尝试着再用管理员权限运行“win-install.cmd"，结果或许会有改变哦！希望能帮到你！
没有这项
@echo off
setlocal ENABLEEXTENSIONS
echo VMware Unlocker 2.0.8
echo ========================
echo (c) Dave Parsons 2011-15
net session >NUL 2>&1
if %errorlevel% neq 0 (
echo Administrator privileges required!
exit
)
pushd %~dp0
set KeyName="HKLM\SOFTWARE\Wow6432Node\VMware, Inc.\VMware Workstation"
:: delims is a TAB followed by a space
for /F "tokens=2* delims= " %%A in ('REG QUERY %KeyName% /v InstallPath') do set InstallPath=%%B
echo VMware is installed at: %InstallPath%
echo Stopping VMware services...
net stop vmware-view-usbd > NUL 2>&1
net stop VMwareHostd > NUL 2>&1
net stop VMAuthdService > NUL 2>&1
net stop VMUSBArbService > NUL 2>&1
taskkill /F /IM vmware-tray.exe > NUL 2>&1
echo Backing up files...
rd /s /q .\backup > NUL 2>&1
mkdir .\backup
mkdir .\backup\x64
xcopy /F /Y "%InstallPath%x64\vmware-vmx.exe" .\backup\x64
xcopy /F /Y "%InstallPath%x64\vmware-vmx-debug.exe" .\backup\x64
xcopy /F /Y "%InstallPath%x64\vmware-vmx-stats.exe" .\backup\x64
xcopy /F /Y "%InstallPath%vmwarebase.dll" .\backup\
echo Patching...
unlocker.exe
echo Getting VMware Tools...
gettools.exe
xcopy /F /Y .\tools\darwin.* "%InstallPath%"
echo Starting VMware services...
net start VMUSBArbService > NUL 2>&1
net start VMAuthdService > NUL 2>&1
net start VMwareHostd > NUL 2>&1
net start vmware-view-usbd > NUL 2>&1
popd
echo Finished!
我很喜欢,太精彩了 好用 谢谢！！ 直接用了2.11
页:
[1]